WebRadio w/I2S -03 . StreamDataの再生

今回は、StrreamDataの再生です。先ずはMP3から。Arduino IDEで、”ファイル”ー>”スケッチ例”ー>”ESP8266 Audio”ー>”StreamMP3FromHTTP”を選んで下さい。サンプルスケッチがロードされます。


#include <Arduino.h>

#ifdef ESP32
    #include <WiFi.h>
#else
    #include <ESP8266WiFi.h>
#endif
#include "AudioFileSourceICYStream.h"
#include "AudioFileSourceBuffer.h"
#include "AudioGeneratorMP3.h"
#include "AudioOutputI2SNoDAC.h"

// To run, set your ESP8266 build to 160MHz, update the SSID info, and upload.

// Enter your WiFi setup here:
const char *SSID = "....";
const char *PASSWORD = "....";

// Randomly picked URL
const char *URL="http://streaming.shoutcast.com/80sPlanet?lang=en-US";

AudioGeneratorMP3 *mp3;
AudioFileSourceICYStream *file;
AudioFileSourceBuffer *buff;
AudioOutputI2SNoDAC *out;

// Called when a metadata event occurs (i.e. an ID3 tag, an ICY block, etc.
void MDCallback(void *cbData, const char *type, bool isUnicode, const char *string)
{
  const char *ptr = reinterpret_cast<const char *>(cbData);
  (void) isUnicode; // Punt this ball for now
  // Note that the type and string may be in PROGMEM, so copy them to RAM for printf
  char s1[32], s2[64];
  strncpy_P(s1, type, sizeof(s1));
  s1[sizeof(s1)-1]=0;
  strncpy_P(s2, string, sizeof(s2));
  s2[sizeof(s2)-1]=0;
  Serial.printf("METADATA(%s) '%s' = '%s'\n", ptr, s1, s2);
  Serial.flush();
}

// Called when there's a warning or error (like a buffer underflow or decode hiccup)
void StatusCallback(void *cbData, int code, const char *string)
{
  const char *ptr = reinterpret_cast<const char *>(cbData);
  // Note that the string may be in PROGMEM, so copy it to RAM for printf
  char s1[64];
  strncpy_P(s1, string, sizeof(s1));
  s1[sizeof(s1)-1]=0;
  Serial.printf("STATUS(%s) '%d' = '%s'\n", ptr, code, s1);
  Serial.flush();
}


void setup()
{
  Serial.begin(115200);
  delay(1000);
  Serial.println("Connecting to WiFi");

  WiFi.disconnect();
  WiFi.softAPdisconnect(true);
  WiFi.mode(WIFI_STA);
  
  WiFi.begin(SSID, PASSWORD);

  // Try forever
  while (WiFi.status() != WL_CONNECTED) {
    Serial.println("...Connecting to WiFi");
    delay(1000);
  }
  Serial.println("Connected");

  audioLogger = &Serial;
  file = new AudioFileSourceICYStream(URL);
  file->RegisterMetadataCB(MDCallback, (void*)"ICY");
  buff = new AudioFileSourceBuffer(file, 2048);
  buff->RegisterStatusCB(StatusCallback, (void*)"buffer");
  out = new AudioOutputI2SNoDAC();
  mp3 = new AudioGeneratorMP3();
  mp3->RegisterStatusCB(StatusCallback, (void*)"mp3");
  mp3->begin(buff, out);
}


void loop()
{
  static int lastms = 0;

  if (mp3->isRunning()) {
    if (millis()-lastms > 1000) {
      lastms = millis();
      Serial.printf("Running for %d ms...\n", lastms);
      Serial.flush();
     }
    if (!mp3->loop()) mp3->stop();
  } else {
    Serial.printf("MP3 done\n");
    delay(1000);
  }
}

これに下記の修正をします。

  • 11行:include “AudioOutputI2SNoDAC.h”をinclude “AudioOutputI2S.h”に変更
  • 16行:const char *SSID = “….”;にルーターのSSIDを入力
  • 17行:const char *PASSWORD = “….”;にルーターのパスワードを入力
  • 20行:const char *URL=”http://streaming.shoutcast.com/80sPlanet?lang=en-US”;
    • ここは再生するStreamDataのURLを入れるのですが、ここは再生されませんでした。const char *URL=”http://199.180.75.118:80/stream”;に変更。
  • 25行:out = new AudioOutputI2SNoDAC();をout = new AudioOutputI2S();に変更

コンパイル後実行して下さい。ジャズの曲が聞こえるはずです。

このスケッチを前回同様、再生する最小限のコードにすると


#include <Arduino.h>
#include <WiFi.h>
#include "AudioFileSourceICYStream.h"
#include "AudioFileSourceBuffer.h"
#include "AudioGeneratorMP3.h"
#include "AudioOutputI2S.h"

// To run, set your ESP8266 build to 160MHz, update the SSID info, and upload.

// Enter your WiFi setup here:
const char *SSID = "XXXXXX";
const char *PASSWORD = "YYYYYY";

// Randomly picked URL
const char *URL="http://199.180.75.118:80/stream";

AudioGeneratorMP3 *mp3;
AudioFileSourceICYStream *file;
AudioFileSourceBuffer *buff;
AudioOutputI2S *out;

void setup()
{
  Serial.begin(115200);
  delay(1000);
  Serial.println("Connecting to WiFi");

  WiFi.disconnect();
  WiFi.softAPdisconnect(true);
  WiFi.mode(WIFI_STA);
  
  WiFi.begin(SSID, PASSWORD);

  // Try forever
  while (WiFi.status() != WL_CONNECTED) {
    Serial.println("...Connecting to WiFi");
    delay(1000);
  }
  Serial.println("Connected");

  file = new AudioFileSourceICYStream(URL);
  buff = new AudioFileSourceBuffer(file, 2048*16);
  out = new AudioOutputI2S();
  mp3 = new AudioGeneratorMP3();
  mp3->begin(buff, out);
}


void loop()
{
  static int lastms = 0;

  if (mp3->isRunning()) {
    if (millis()-lastms > 1000) {
      lastms = millis();
      Serial.printf("Running for %d ms...\n", lastms);
      Serial.flush();
     }
    if (!mp3->loop()) mp3->stop();
  } else {
    Serial.printf("MP3 done\n");
    delay(1000);
  }
}

前のコードではたまに再生が止まったので、42行のバッファーサイズを2048から2048x16に増やしました。これにより再生の止まる回数が減りました。

このスケッチを、”WebRadio w/I2S -02 . MP3/AAC ファイルの再生”のMP3再生最小コードと再生部の比較すると

  • file = new AudioFileSourceSPIFFS(“/pno-cs.mp3”); -> file = new AudioFileSourceICYStream(URL);
    • 再生先の指定。MP3がファイルを指定しているのに対してStreamはURLを指定。
    • ICYとは、”I Can Yell”? SHOUTcast ?
  • Stream側に、buff = new AudioFileSourceBuffer(file, 2048*16);が追加
    • ダウンロードしたデータを一時貯めるバッファーが必要なのでしょう。

後は、同じ処理を行っています。ラジオ局を固定ならこれで十分にWebRadioです。電源を入れるだけで再生します。

次はAAC

上記に最小スケッチのMP3に関する箇所をAACに変更するのみで再生出来る様です。MP3のスケッチから


#include <Arduino.h>
#include <WiFi.h>
#include "AudioFileSourceICYStream.h"
#include "AudioFileSourceBuffer.h"
#include "AudioGeneratorAAC.h"
#include "AudioOutputI2S.h"

// To run, set your ESP8266 build to 160MHz, update the SSID info, and upload.

// Enter your WiFi setup here:
const char *SSID = "XXXXXX";
const char *PASSWORD = "YYYYYY";

// Randomly picked URL
const char *URL="http://107.191.33.98:8232/stream/1";

AudioGeneratorAAC *aac;
AudioFileSourceICYStream *file;
AudioFileSourceBuffer *buff;
AudioOutputI2S *out;

void setup()
{
  Serial.begin(115200);
  delay(1000);
  Serial.println("Connecting to WiFi");

  WiFi.disconnect();
  WiFi.softAPdisconnect(true);
  WiFi.mode(WIFI_STA);
  
  WiFi.begin(SSID, PASSWORD);

  // Try forever
  while (WiFi.status() != WL_CONNECTED) {
    Serial.println("...Connecting to WiFi");
    delay(1000);
  }
  Serial.println("Connected");

  file = new AudioFileSourceICYStream(URL);
  buff = new AudioFileSourceBuffer(file, 2048*16);
  out = new AudioOutputI2S();
  aac = new AudioGeneratorAAC();
  aac->begin(buff, out);
}

void loop()
{
    if (aac->isRunning()) {
        if (!aac->loop()) aac->stop();
    } else {
    Serial.printf("AAC done\n");
    delay(1000);
  }
}
  • 5行:include “AudioGeneratorMP3.h”をinclude “AudioGeneratorAAC.h”に変更
  • 15行:const char *URL=”http://199.180.75.118:80/stream”;をAAC StreamURLのconst char *URL=”http://107.191.33.98:8232/stream/1″;に変更
  • 17行:AudioGeneratorMP3 *mp3;をAudioGeneratorAAC *aac;に変更
  • 44行:mp3 = new AudioGeneratorMP3();をaac = new AudioGeneratorAAC();に変更
  • 45行:mp3->begin(buff, out);をaac->begin(buff, out);に変更
  • 50行以降: mp3の箇所をaacに変更。再生時間を表示していた、if (millis()-lastms > 1000)の部分とstatic int lastms = 0;を削除

コンパイル実行して下さい。ラテン系の局が再生されるはずです。

次回は、WebServerをインストールしてラジオ局の選択、音量調整等を行いたいと思います。