写真を撮るサイトを見つけました

写真を撮ってmicro_SDにセーブする方法を説明しているサイトを見つけました。”ESP32-CAM Take Photo and Save to MicroSD Card”。そのものズバリの題名です。そこに有るスケッチです。

/*********
  Rui Santos
  Complete project details at https://RandomNerdTutorials.com/esp32-cam-take-photo-save-microsd-card
  
  IMPORTANT!!! 
   - Select Board "AI Thinker ESP32-CAM"
   - GPIO 0 must be connected to GND to upload a sketch
   - After connecting GPIO 0 to GND, press the ESP32-CAM on-board RESET button to put your board in flashing mode
  
  Permission is hereby granted, free of charge, to any person obtaining a copy
  of this software and associated documentation files.
  The above copyright notice and this permission notice shall be included in all
  copies or substantial portions of the Software.
*********/

#include "esp_camera.h"
#include "Arduino.h"
#include "FS.h"                // SD Card ESP32
#include "SD_MMC.h"            // SD Card ESP32
#include "soc/soc.h"           // Disable brownour problems
#include "soc/rtc_cntl_reg.h"  // Disable brownour problems
#include "driver/rtc_io.h"
#include <EEPROM.h>            // read and write from flash memory

// define the number of bytes you want to access
#define EEPROM_SIZE 1

// Pin definition for CAMERA_MODEL_AI_THINKER
#define PWDN_GPIO_NUM     32
#define RESET_GPIO_NUM    -1
#define XCLK_GPIO_NUM      0
#define SIOD_GPIO_NUM     26
#define SIOC_GPIO_NUM     27

#define Y9_GPIO_NUM       35
#define Y8_GPIO_NUM       34
#define Y7_GPIO_NUM       39
#define Y6_GPIO_NUM       36
#define Y5_GPIO_NUM       21
#define Y4_GPIO_NUM       19
#define Y3_GPIO_NUM       18
#define Y2_GPIO_NUM        5
#define VSYNC_GPIO_NUM    25
#define HREF_GPIO_NUM     23
#define PCLK_GPIO_NUM     22

int pictureNumber = 0;

void setup() {
  WRITE_PERI_REG(RTC_CNTL_BROWN_OUT_REG, 0); //disable brownout detector
 
  Serial.begin(115200);
  //Serial.setDebugOutput(true);
  //Serial.println();
  
  camera_config_t config;
  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sscb_sda = SIOD_GPIO_NUM;
  config.pin_sscb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.pixel_format = PIXFORMAT_JPEG; 
  
  if(psramFound()){
    config.frame_size = FRAMESIZE_UXGA; // FRAMESIZE_ + QVGA|CIF|VGA|SVGA|XGA|SXGA|UXGA
    config.jpeg_quality = 10;
    config.fb_count = 2;
  } else {
    config.frame_size = FRAMESIZE_SVGA;
    config.jpeg_quality = 12;
    config.fb_count = 1;
  }
  
  // Init Camera
  esp_err_t err = esp_camera_init(&config);
  if (err != ESP_OK) {
    Serial.printf("Camera init failed with error 0x%x", err);
    return;
  }
  
  //Serial.println("Starting SD Card");
  if(!SD_MMC.begin()){
    Serial.println("SD Card Mount Failed");
    return;
  }
  
  uint8_t cardType = SD_MMC.cardType();
  if(cardType == CARD_NONE){
    Serial.println("No SD Card attached");
    return;
  }
    
  camera_fb_t * fb = NULL;
  
  // Take Picture with Camera
  fb = esp_camera_fb_get();  
  if(!fb) {
    Serial.println("Camera capture failed");
    return;
  }
  // initialize EEPROM with predefined size
  EEPROM.begin(EEPROM_SIZE);
  pictureNumber = EEPROM.read(0) + 1;

  // Path where new picture will be saved in SD Card
  String path = "/picture" + String(pictureNumber) +".jpg";

  fs::FS &fs = SD_MMC; 
  Serial.printf("Picture file name: %s\n", path.c_str());
  
  File file = fs.open(path.c_str(), FILE_WRITE);
  if(!file){
    Serial.println("Failed to open file in writing mode");
  } 
  else {
    file.write(fb->buf, fb->len); // payload (image), payload length
    Serial.printf("Saved file to path: %s\n", path.c_str());
    EEPROM.write(0, pictureNumber);
    EEPROM.commit();
  }
  file.close();
  esp_camera_fb_return(fb); 
  
  // Turns off the ESP32-CAM white on-board LED (flash) connected to GPIO 4
  pinMode(4, OUTPUT);
  digitalWrite(4, LOW);
  rtc_gpio_hold_en(GPIO_NUM_4);
  
  delay(2000);
  Serial.println("Going to sleep now");
  delay(2000);
  esp_deep_sleep_start();
  Serial.println("This will never be printed");
}

void loop() {
  
}

これをコンパイルして実行して見て下さい。確かにmicro_SDに写真が保存されます。ただ、写真を撮る時にLED_Flashが光ります。意図的か、それともmicro_SDに保存する時のあれか?

スケッチを見ると

スケッチの内容はリンク先に動画で説明されています。

  • 56行から76行:カメラに必要なパラメータに設定
  • 78行から86行: PSRAMの有無により写真の解像度を設定
  • 89行:カメラの初期設定
  • 110行:ここで、写真を撮影している様です。
  • 122行から135行:SD_MMCと有るので、microSD用の関数を使用していると思われる。撮影時にFlashが光るのはこのためか。
  • 130行: メディアへの書込。
  • それ以降: 撮影後、Flashを消灯して、Deep_Sleepモードに入る。

眩しいので取り敢えずFlashを消す

このスケッチを元に、Flashを光らせない様に変更します。変更内容は、”ESP32CAM(micro_SDを使う)”と同じです。書込の方式を、SDカード方式にするだけです。また、Flashが光らなくなったので、撮影の終了確認用にモニターに、”Take a photo” と表示させています。

#include "esp_camera.h"
#include "Arduino.h"
#include "FS.h"                 // SD Card ESP32
#include "SD.h"                 // Changed          
#include <EEPROM.h>            // read and write from flash memory

// define the number of bytes you want to access
#define EEPROM_SIZE 1

// Pin definition for CAMERA_MODEL_AI_THINKER
#define PWDN_GPIO_NUM     32
#define RESET_GPIO_NUM    -1
#define XCLK_GPIO_NUM      0
#define SIOD_GPIO_NUM     26
#define SIOC_GPIO_NUM     27

#define Y9_GPIO_NUM       35
#define Y8_GPIO_NUM       34
#define Y7_GPIO_NUM       39
#define Y6_GPIO_NUM       36
#define Y5_GPIO_NUM       21
#define Y4_GPIO_NUM       19
#define Y3_GPIO_NUM       18
#define Y2_GPIO_NUM        5
#define VSYNC_GPIO_NUM    25
#define HREF_GPIO_NUM     23
#define PCLK_GPIO_NUM     22

#define sd_sck  14
#define sd_mosi 15
#define sd_ss   13
#define sd_miso  2

int pictureNumber = 0;

void setup() {
 
  Serial.begin(115200);
  
  camera_config_t config;
  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sscb_sda = SIOD_GPIO_NUM;
  config.pin_sscb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.pixel_format = PIXFORMAT_JPEG; 
  config.frame_size = FRAMESIZE_UXGA; // FRAMESIZE_ + QVGA|CIF|VGA|SVGA|XGA|SXGA|UXGA
  config.jpeg_quality = 10;
  config.fb_count = 2;

  // Init Camera
   esp_camera_init(&config);

  // Take Picture with Camera
  camera_fb_t * fb = NULL;
  fb = esp_camera_fb_get();  

  // initialize EEPROM with predefined size
  EEPROM.begin(EEPROM_SIZE);
  pictureNumber = EEPROM.read(0) + 1;

  // Path where new picture will be saved in SD Card
  String path = "/picture" + String(pictureNumber) +".jpg";

  SPI.begin(sd_sck, sd_miso, sd_mosi, sd_ss);
  SD.begin(sd_ss);
  
  File file = SD.open(path.c_str(), FILE_WRITE);
  file.write(fb->buf, fb->len); // payload (image), payload length
  EEPROM.write(0, pictureNumber);
  EEPROM.commit();

  file.close();
  esp_camera_fb_return(fb); 

  Serial.printf("Take a photo.\n");
}

void loop() {
  
}

オリジナルについて

  • パワーセーブ関係を削除
  • エラー処理関係を削除
  • config設定でpsramFound()が真だったのでそちらを選択(61から63行)

を行い、撮影時にFlashが光らな様に

  • 4行:SD用のヘッダーファイルの読み込み
  • 29行から32行: ピンアサインの定義
  • 79行から80行: SD方式への変換
  • 82行:SDへ保存
  • 90行:スケッチ終了。Take a photo. 表示

の修正を行っています。これで撮影時に眩しく無くなりました。このスケッチ、パラメータの設定部分を抜けば、66行目から88行目がメインとなります。

写真関係

  • 66行:esp_camera_init(&config);
    • configを用いてカメラの初期化。
    • 戻り値: エラー:0 OK:1
  • 69行:camera_fb_t * fb = NULL;
    • camera_fb_t型のポインター宣言。
    • SDにセーブする時に使用されている。
    • esp_camera_init()同様、戻り値でエラー判断。
  • 70行:fb = esp_camera_fb_get();
    • ここで撮影している模様。
  • 88行:esp_camera_fb_return(fb);
    • カメラ操作の最後にこの関数を使用。

EEPROM関係

  • 73行:EEPROM.begin(EEPROM_SIZE);
    • 使用するサイズを、EEPROM_SIZEで指定
  • 74行:pictureNumber = EEPROM.read(0) + 1;
    • EEPROM.read(0) EEPROMの読み出し関数。引数はデータのアドレス?
  • 84行:EEPROM.write(0, pictureNumber);
    • EEPROMへの書込関数。引数は、アドレスとデータ?複数書く場合は?
  • 85行:EEPROM.commit();
    • 関数名から、書込確認作業を行う様に思えます。

PSRAM関係

  • 写真のデータは、PSRAMに保存されるはず。
  • でもこのスケッチで直接PSRAMを操作するコードは見当たりません。
  • 83行目に写真データの読み出しがある。

これで写真を撮ってSDに保存出来るようになりました。次回はこれを使って、”タイムラプス”をやって見たいと思います。

シェアする

  • このエントリーをはてなブックマークに追加

フォローする